5 POKE55,.:POKE56,56:CLR
10 DV=PEEK(186):IFDV<8THENDV=8
15 PRINT"[147]":POKE53280,.:POKE53281,.
16 POKE53371,.
17 POKE53272,31
18 AD=49152
20 SYSAD:SYSAD+12
30 GOSUB930:REM INITIALIZE DATA ARRAYS
40 PRINT"[147]":SYSAD+9,8
45 PRINTTAB(3)"[150] [207][218][207][206][197]-[196][197][208][204][197][212][197][196] [213][214] [196][193][205][193][199][197] [201][206][196][197][216] "
50 PRINT:PRINT"[159] [204]ATITUDE IN DEGREES: ";:L9%=6:GOSUB1250:L=Q9:LA=L/57.296
60 PRINT"[159] [205]ONTH (1-12): ";:L9%=2:GOSUB1250:M=Q9
65 IFM=<0ORM>12THENPRINT"[145][145]":GOTO60
70 PRINT"[159] [200]OURS FROM LOCAL NOON: ";:L9%=2:GOSUB1250:T=Q9:T=ABS(T)
80 DS=.408*SIN(.523*(M-3.7)):REM DECL OF SUN (RADIANS)
90 HA=.262*T:REM HOUR ANGLE OF THE SUN (RADIANS)
100 CZ=SIN(LA)*SIN(DS)+COS(LA)*COS(DS)*COS(HA)
110 IFCZ<=0THENPRINT"[145][145]":GOTO70
120 ZS=ATN(SQR(1-CZ*CZ)/CZ):REM SUN'S ZENITH DIST. (RAD)
180 PRINT"[159] [200]EIGHT ABOVE SEA LEVEL [158](FT): ";:L9%=6:GOSUB1250:HH=Q9:H=HH/3280
190 PRINT"[159] [193]EROSOL EXTINCTION [158](.1-.5): ";:L9%=3:GOSUB1250:KK=Q9
200 BE=KK/2.36
210 PRINT"[159] [211]URFACE ALBEDO (%): ";:L9%=2:GOSUB1250:S1=Q9:SA=S1/100
230 REM OTHER ADJUSTABLE PARAMETERS
250 ET=3600:REM EXPOSURE TIME SEC
260 ZP=ZS:REM ANGLE (RAD), ZENITH TO SURFACE NORMAL
270 SS=0:REM ANGLE (RAD), SUN TO SURFACE NORMAL
272 PRINT"[159] [193]RE YOU WEARING SUNBLOCK[158]? [217]/[206]":POKE198,.
274 GETHC$:IFHC$<>"Y"ANDHC$<>"N"THEN274
275 IFHC$="N"THENTW=1:GOTO290
276 SYSAD+9,6
277 PRINT"[159] [215]HAT STRENGTH OF SUNBLOCK?: ";:L9%=2:GOSUB1250:SB=Q9
279 TW=1/SB
280 REM TW=1 UV FRAC. TRANSMITTED BY WINDOW, LOTION
290 F1=1:SYSAD+9,6:REM FRACTION OF SKY THAT IS CLEAR
300 F2=1:REM FRACTION OF GROUND IN SUNLIGHT
301 PRINT"[159] [193]RE YOU IN THE SHADE?:[158] [217]/[206]":POKE198,.
302 GETHC$:IFHC$<>"Y"ANDHC$<>"N"THEN302
303 IFHC$="Y"THENSH=0
304 IFHC$="N"THENSH=1
305 SYSAD+9,6
308 PRINTTAB(5)"[215]HICH [211]KIN [212]ONE ARE YOU?"
309 PRINT"[158]1.[155][215]HITE [158]2.[155][207]RIENTAL[150]-[155][207]LIVE [195]OMPLEXION"
310 PRINT"[158]3.[155][204]T [194]ROWN[150]-[155][204]T [212]ANNED [158]4.[155][205]EDIUM [194]ROWN"
311 PRINT"[158]5.[155][214]ERY [212]ANNED [158]6.[155][204]IGHT [194]LACK [158]7.[155][194]LACK"
312 GETHC$:IFHC$<"1"ORHC$>"7"THEN312
313 SYSAD+9,6
314 IFHC$="1"THENN=1
315 IFHC$="2"THENN=.9
316 IFHC$="3"THENN=.8
317 IFHC$="4"THENN=.7
318 IFHC$="5"THENN=.5
319 IFHC$="6"THENN=.3
320 IFHC$="7"THENN=.1
330 RE=6378.14:REM EARTH RADIUS (KM)
340 OL=15:REM OZONE LOSS (%)
350 HO=23:REM HEIGHT OF OZONE LAYER
360 HG=8.2:REM GAS SCALE HEIGHT (KM)
370 HA=1.5:REM AEROSOL SCALE HEIGHT (KM)
380 DS=1:REM DISTANCE FROM THE SUN (AU)
400 REM THICKNESS OF OZONE LAYER
420 RA=30*(M-3.7)/57.296
430 DO=(1-OL/100)*(3+.4*(LA*COS(RA)-COS(3*LA)))
450 REM AIRMASS FOR EACH COMPONENT
470 XO=(1-(SIN(ZS)/(1+((HO-H)/RE)))^2)^-.5
480 XG=1/(COS(ZS)+.01*SQR(HG)*EXP(-30*COS(ZS)/SQR(HG)))
490 XA=1/(COS(ZS)+.01*SQR(HA)*EXP(-30*COS(ZS)/SQR(HA)))
510 REM DO FOR EACH WAVELENGTH
530 POKE214,15:PRINT:PRINT"    [195] [207] [205] [208] [213] [212] [201] [206] [199]..."
550 ED=0
560 FORJ=1TO20
570 W=.275+J*.005:REM WAVELENGTH (MICRONS)
590 REM BRIGHTNESS OF SUNLIGHT, DIFFUSE SKY LIGHT
600 SYSAD+9,5:REM AND GROUND LIGHT
610 KO=OZ(J)*(DO/3)
620 KG=.0107*EXP(-H/HG)*(W^-4)
630 KA=BE*(W^-1.3)
640 OT=10^(-.4*(KO*OX))
650 TA=10^(-.4*(KG*XG+KA*XA))
660 D=.5*(COS(ZS)^.33)
670 IS=FS(J)*OT*TA*TW*SH*COS(SS)*(DS^-2)
680 ID=FS(J)*OT*(1-TA)*D
690 ID=FS(J)*OT*(1-TA)*D*TA*SA+ID
700 ID=FS(J)*OT((1-TA)^2)*SA*(D^2)+ID
710 ID=ID*TW*F1*(COS(ZS/2)^2)*(DS^-2)
720 IG=FS(J)*OT*SA*(TA+D*(1-TA))
730 IG=IG*TW*F2*(SIN(ZS/2)^2)*(DS^-2)
740 I=IS+ID+IG:REM TOTAL FLUX ON SKIN (ERG/CM^2/SEC/ANSTR)
760 REM FIND EFFECTIVE DOSE BY NUMERICAL INTEGRATION
770 REM THE MINIMUM ERYTHEMA DOSE AT 2900 ANSTR
780 REM IS 2.3E6 ERG/CM^2 (PARRISH)
800 EF=I*ET*(AS(J)*N)*50/2.3E6
810 ED=ED+EF
830 NEXT J
850 REM REPORT RESULT
870 POKE214,15:PRINT:PRINT"[156][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162]":SYSAD+9,11
880 PRINT"[153] [212]OTAL EFFECTIVE DOSE:";ED
890 PRINT"[153] ([197]XPOSURE TIME HR.) ";ET/3600
895 PRINT"[153] [194]URNING STARTS IN MINS.";ET/(3600*ED)*60
899 GOSUB40000
910 GOTO40
930 REM DIM AND READ DATA
950 DIMOZ(20),FS(20),AS(20)
960 FORJ=1TO20:READOZ(J):NEXT
970 FORJ=1TO20:READFS(J):NEXT
980 FORJ=1TO20:READAS(J):NEXT
990 RETURN
1010 REM OZ ARRAY (OZONE EFFECT)
1020 DATA 34,25,18,9,3.2,1.8,.9,.46,.24,.17
1030 DATA .06,.05,.02,.01,.002,.001,0,0,0,0
1050 REM FS ARRAY (SOLAR FLUX AT 1 AU IN ERG/CM^2/SEC/ANSTR
1060 DATA24,31,38,45,52,58,64,70,75,79
1070 DATA83,87,91,93,95,97,99,104,107,104
1090 REM AS ARRAY (ACTION SPECTRUM, MCKINLEY & DIFFEY)
1100 DATA 1,1,1,1,.65,.22,.074,.025,.0086,.003
1110 DATA .0014,.0012,.00097,.00081,.00068,.00057
1120 DATA .00048,.0004,.00034,.00029
1250 Q9$="":POKE198,.
1255 GETA$
1260 POKE646,RND(1)*15+1:PRINT"*[157]";:IFA$=""THEN1255
1265 IFA$=CHR$(13)THENPRINT" ":Q9=VAL(Q9$):RETURN
1270 IF(A$=CHR$(20)ANDLEN(Q9$))THENQ9$=LEFT$(Q9$,LEN(Q9$)-1):GOTO1300
1275 IFLEN(Q9$)>=L9%THENSYSAD+9,2:GOTO1255
1280 IF(A$>="0"ANDA$<="9")ORA$="."ORA$="-"THEN1290
1285 GOTO1255
1290 Q9$=Q9$+A$
1295 PRINT""A$;:SYSAD+9,6:GOTO1255
1300 PRINT" [157][157] [157]";:GOTO1255
10000 D=PEEK(186):N$="UV DAMAGE":OPEN15,D,15,"S0:"+N$:CLOSE15:SAVEN$,D:END
40000 POKE214,21:PRINT:PRINTTAB(8)"[159](1[159]) [212]RY ANOTHER ONE
40010 [153][163]8)"OPEN(2OPEN) (null)O (null)(null)RIGHT$(null)VAL(null)(null)VAL (null)ENU
40020 SYSAD+9,2:POKE198,0
40030 GETA$:IFA$<"1"ORA$>"2"THEN40030
40040 IFA$="1"THENRETURN
40050 SYSAD+15
40060 PRINT"[147][144]LOAD"CHR$(34)"B.UNIVERSE II"CHR$(34)","DV
40070 PRINT"RUN28"
40080 POKE631,13:POKE632,13:POKE198,2:END